SWAMPy

✎ CARVE FLESH

EDITING: doublebitand.cocci

// SPDX-License-Identifier: GPL-2.0-only
/// Find bit operations that include the same argument more than once
//# One source of false positives is when the argument performs a side
//# effect.  Another source of false positives is when a neutral value
//# such as 0 for | is used to indicate no information, to maintain the
//# same structure as other similar expressions
///
// Confidence: Moderate
// Copyright: (C) 2010 Nicolas Palix, DIKU.
// Copyright: (C) 2010 Julia Lawall, DIKU.
// Copyright: (C) 2010 Gilles Muller, INRIA/LiP6.
// URL: https://coccinelle.gitlabpages.inria.fr/website
// Comments:
// Options: --no-includes --include-headers

virtual context
virtual org
virtual report

@r expression@
expression E;
position p;
@@

(
*        E@p
         & ... & E
|
*        E@p
         | ... | E
|
*        E@p
         & ... & !E
|
*        E@p
         | ... | !E
|
*        !E@p
         & ... & E
|
*        !E@p
         | ... | E
)

@script:python depends on org@
p << r.p;
@@

cocci.print_main("duplicated argument to & or |",p)

@script:python depends on report@
p << r.p;
@@

coccilib.report.print_report(p[0],"duplicated argument to & or |")

CANCEL

Name	Type	Size	Modified	Actions
↩ ..	DIR	—	—
📄 doublebitand.cocci	COCCI	1.1 KB	2024-03-10 20:38	EDIT
📄 doubletest.cocci	COCCI	1.1 KB	2024-03-10 20:38	EDIT
📄 odd_ptr_err.cocci	COCCI	2.1 KB	2024-03-10 20:38	EDIT
📄 unsigned_lesser_than_zero.cocci	COCCI	2.2 KB	2024-03-10 20:38	EDIT