SWAMPy

✎ CARVE FLESH

EDITING: clk_put.cocci

// SPDX-License-Identifier: GPL-2.0-only
/// Find missing clk_puts.
///
//# This only signals a missing clk_put when there is a clk_put later
//# in the same function.
//# False positives can be due to loops.
//
// Confidence: Moderate
// Copyright: (C) 2012 Julia Lawall, INRIA/LIP6.
// Copyright: (C) 2012 Gilles Muller, INRIA/LiP6.
// URL: https://coccinelle.gitlabpages.inria.fr/website
// Comments:
// Options:

virtual context
virtual org
virtual report

@clk@
expression e;
statement S,S1;
int ret;
position p1,p2,p3;
@@

e = clk_get@p1(...)
... when != clk_put(e)
if (<+...e...+>) S
... when any
    when != clk_put(e)
    when != if (...) { ... clk_put(e); ... }
(
 if (ret == 0) S1
|
if (...)
   { ...
     return 0; }
|
if (...)
   { ...
     return <+...e...+>; }
|
*if@p2 (...)
   { ... when != clk_put(e)
         when forall
     return@p3 ...; }
)
... when any
clk_put(e);

@script:python depends on org@
p1 << clk.p1;
p2 << clk.p2;
p3 << clk.p3;
@@

cocci.print_main("clk_get",p1)
cocci.print_secs("if",p2)
cocci.print_secs("needed clk_put",p3)

@script:python depends on report@
p1 << clk.p1;
p2 << clk.p2;
p3 << clk.p3;
@@

msg = "ERROR: missing clk_put; clk_get on line %s and execution via conditional on line %s" % (p1[0].line,p2[0].line)
coccilib.report.print_report(p3[0],msg)

CANCEL

Name	Type	Size	Modified	Actions
↩ ..	DIR	—	—
📄 clk_put.cocci	COCCI	1.3 KB	2025-09-28 21:39	EDIT
📄 devm_free.cocci	COCCI	2.5 KB	2025-09-28 21:39	EDIT
📄 ifnulldev_put.cocci	COCCI	1.1 KB	2025-09-28 21:39	EDIT
📄 ifnullfree.cocci	COCCI	1.3 KB	2025-09-28 21:39	EDIT
📄 iounmap.cocci	COCCI	1.3 KB	2025-09-28 21:39	EDIT
📄 kfree.cocci	COCCI	1.8 KB	2025-09-28 21:39	EDIT
📄 kfreeaddr.cocci	COCCI	646 B	2025-09-28 21:39	EDIT
📄 pci_free_consistent.cocci	COCCI	1.3 KB	2025-09-28 21:39	EDIT
📄 put_device.cocci	COCCI	1.3 KB	2025-09-28 21:39	EDIT