SWAMPy

✎ CARVE FLESH

EDITING: elide-arity-checks.scm

;;; Continuation-passing style (CPS) intermediate language (IL)

;;;; This library is free software; you can redistribute it and/or
;;;; modify it under the terms of the GNU Lesser General Public
;;;; License as published by the Free Software Foundation; either
;;;; version 3 of the License, or (at your option) any later version.
;;;;
;;;; This library is distributed in the hope that it will be useful,
;;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
;;;; Lesser General Public License for more details.
;;;;
;;;; You should have received a copy of the GNU Lesser General Public
;;;; License along with this library; if not, write to the Free Software
;;;; Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA

;;; Commentary:
;;;
;;; If we have a $callk to a $kfun that has a $kclause, in most cases we
;;; can skip arity checks because the caller knows what arity the callee
;;; is expecting.
;;;
;;; Code:

(define-module (language cps elide-arity-checks)
  #:use-module (ice-9 match)
  #:use-module (language cps)
  #:use-module (language cps intmap)
  #:use-module (language cps utils)
  #:use-module (language cps with-cps)
  #:export (elide-arity-checks))

(define (arity-matches? arity self proc args)
  (match arity
    (($ $arity req () #f () #f)
     (= (+ (length req) (if self 1 0))
        (+ (length args) (if proc 1 0))))
    (_ #f)))

(define (maybe-elide-arity-check cps kfun proc args)
  (match (intmap-ref cps kfun)
    (($ $kfun fsrc meta self ktail kentry)
     (match (and kentry (intmap-ref cps kentry))
       (($ $kclause (? (lambda (arity)
                         (arity-matches? arity self proc args))
                       arity)
           kbody #f)
        ;; This is a compatible $callk to a $kfun that checks its arity
        ;; and has no alternate; arrange to elide the check.
        (match (intmap-ref cps kbody)
          (($ $kargs fnames fvars term)
           (match term
             (($ $continue (? (lambda (k) (eq? k ktail))) _
                 ($ $callk kfun'
                    (? (lambda (proc') (eq? proc' self)))
                    (? (lambda (args) (equal? args fvars)))))
              ;; This function already trampolines out to another
              ;; function; forward this call there.  Could recurse but
              ;; we shouldn't need to, and we don't so as to avoid
              ;; divergence.
              (with-cps cps
                (build-exp
                  ($callk kfun' proc args))))
             (_
              ;; Define a new unchecked function containing the body of
              ;; this function.
              (let ((self' (and self (fresh-var)))
                    (fvars' (map (lambda (_) (fresh-var)) fvars)))
                (with-cps cps
                  ;; Entry of new kfun' is the $kargs kbody.
                  (letk kfun' ($kfun fsrc meta self ktail kbody))
                  (letk ktail' ($ktail))
                  (letk kbody' ($kargs fnames fvars'
                                 ($continue ktail' fsrc
                                   ($callk kfun' self' fvars'))))
                  (letk kentry' ($kclause ,arity kbody' #f))
                  (setk kfun ($kfun fsrc meta self' ktail' kentry'))
                  ;; Dispatch source $callk to new kfun'.
                  (build-exp
                    ($callk kfun' proc args)))))))))
       (_
        ;; Either this is already a $callk to a "raw" $kfun (one that
        ;; doesn't check its arity), in which case we're good; or a call
        ;; with possibly incompatible arity, or a call to a case-lambda,
        ;; in which case we punt for now.
        (with-cps cps
          (build-exp ($callk kfun proc args))))))))

;; This transformation removes references to arity-checking $kfun's, but
;; doesn't remove them, leaving that to renumbering or DCE to fix up.
(define (elide-arity-checks cps)
  (with-fresh-name-state cps
    (persistent-intmap
     (intmap-fold
      (lambda (label cont cps)
        (match cont
          (($ $kargs names vars
              ($ $continue k src ($ $callk kfun proc args)))
           (with-cps cps
             (let$ exp (maybe-elide-arity-check kfun proc args))
             (setk label ($kargs names vars
                           ($continue k src ,exp)))))
          (_ cps)))
      (persistent-intmap cps)
      (transient-intmap cps)))))

CANCEL

Name	Type	Size	Modified	Actions
↩ ..	DIR	—	—
📄 closure-conversion.scm	SCM	37.3 KB	2023-01-23 21:52	EDIT
📄 compile-bytecode.scm	SCM	30.7 KB	2023-01-23 21:52	EDIT
📄 contification.scm	SCM	23.5 KB	2023-01-23 21:52	EDIT
📄 cse.scm	SCM	32.6 KB	2023-01-23 21:52	EDIT
📄 dce.scm	SCM	18 KB	2023-01-23 21:52	EDIT
📄 devirtualize-integers.scm	SCM	11.3 KB	2023-01-23 21:52	EDIT
📄 dump.scm	SCM	11.6 KB	2023-01-23 21:52	EDIT
📄 effects-analysis.scm	SCM	27.2 KB	2023-01-23 21:52	EDIT
📄 elide-arity-checks.scm	SCM	4.4 KB	2023-01-23 21:52	EDIT
📄 graphs.scm	SCM	13.8 KB	2023-01-23 21:52	EDIT
📄 intmap.scm	SCM	28.3 KB	2023-01-23 21:52	EDIT
📄 intset.scm	SCM	29.6 KB	2023-01-23 21:52	EDIT
📄 licm.scm	SCM	14.7 KB	2023-01-23 21:52	EDIT
📄 loop-instrumentation.scm	SCM	2.6 KB	2023-01-23 21:52	EDIT
📄 optimize.scm	SCM	5.7 KB	2023-01-23 21:52	EDIT
📄 peel-loops.scm	SCM	14.5 KB	2023-01-23 21:52	EDIT
📄 prune-top-level-scopes.scm	SCM	2.1 KB	2023-01-23 21:52	EDIT
📄 reify-primitives.scm	SCM	23.9 KB	2023-01-23 21:52	EDIT
📄 renumber.scm	SCM	10.2 KB	2023-01-23 21:52	EDIT
📄 return-types.scm	SCM	6.5 KB	2023-01-23 21:52	EDIT
📄 rotate-loops.scm	SCM	10.4 KB	2023-01-23 21:52	EDIT
📄 self-references.scm	SCM	3.1 KB	2023-01-23 21:52	EDIT
📄 simplify.scm	SCM	10.5 KB	2023-01-23 21:52	EDIT
📄 slot-allocation.scm	SCM	33.4 KB	2023-01-23 21:52	EDIT
📄 spec.scm	SCM	1.8 KB	2023-01-23 21:52	EDIT
📄 specialize-numbers.scm	SCM	43.5 KB	2023-01-23 21:52	EDIT
📄 specialize-primcalls.scm	SCM	6.7 KB	2023-01-23 21:52	EDIT
📄 split-rec.scm	SCM	7.6 KB	2023-01-23 21:52	EDIT
📄 switch.scm	SCM	18 KB	2023-01-23 21:52	EDIT
📄 type-checks.scm	SCM	3.1 KB	2023-01-23 21:52	EDIT
📄 type-fold.scm	SCM	28.5 KB	2023-01-23 21:52	EDIT
📄 types.scm	SCM	80.7 KB	2023-01-23 21:52	EDIT
📄 utils.scm	SCM	18.1 KB	2023-01-23 21:52	EDIT
📄 verify.scm	SCM	12.5 KB	2023-01-23 21:52	EDIT
📄 with-cps.scm	SCM	5.7 KB	2023-01-23 21:52	EDIT