SWAMPy

✎ CARVE FLESH

EDITING: extract.awk

# extract.awk --- extract files and run programs from Texinfo files
#
# Arnold Robbins, arnold@skeeve.com, Public Domain
# May 1993
# Revised September 2000

BEGIN    { IGNORECASE = 1 }

/^@c(omment)?[ \t]+system/ {
    if (NF < 3) {
        e = ("extract: " FILENAME ":" FNR)
        e = (e  ": badly formed `system' line")
        print e > "/dev/stderr"
        next
    }
    $1 = ""
    $2 = ""
    stat = system($0)
    if (stat != 0) {
        e = ("extract: " FILENAME ":" FNR)
        e = (e ": warning: system returned " stat)
        print e > "/dev/stderr"
    }
}
/^@c(omment)?[ \t]+file/ {
    if (NF != 3) {
        e = ("extract: " FILENAME ":" FNR ": badly formed `file' line")
        print e > "/dev/stderr"
        next
    }
    if ($3 != curfile) {
        if (curfile != "")
            filelist[curfile] = 1   # save to close later
        curfile = $3
    }

for (;;) {
        if ((getline line) <= 0)
            unexpected_eof()
        if (line ~ /^@c(omment)?[ \t]+endfile/)
            break
        else if (line ~ /^@(end[ \t]+)?group/)
            continue
        else if (line ~ /^@c(omment+)?[ \t]+/)
            continue
        if (index(line, "@") == 0) {
            print line > curfile
            continue
        }
        n = split(line, a, "@")
        # if a[1] == "", means leading @,
        # don't add one back in.
        for (i = 2; i <= n; i++) {
            if (a[i] == "") { # was an @@
                a[i] = "@"
                if (a[i+1] == "")
                    i++
            }
        }
        print join(a, 1, n, SUBSEP) > curfile
    }
}
END {
    close(curfile)          # close the last one
    for (f in filelist)     # close all the rest
        close(f)
}
function unexpected_eof()
{
    printf("extract: %s:%d: unexpected EOF or error\n",
                     FILENAME, FNR) > "/dev/stderr"
    exit 1
}

CANCEL

Name	Type	Size	Modified	Actions
↩ ..	DIR	—	—
📄 alarm.awk	AWK	2.3 KB	2022-11-17 16:36	EDIT
📄 anagram.awk	AWK	1.3 KB	2022-11-17 16:36	EDIT
📄 awksed.awk	AWK	515 B	2022-11-17 16:36	EDIT
📄 cut.awk	AWK	3.6 KB	2022-11-17 16:36	EDIT
📄 dupword.awk	AWK	507 B	2022-11-17 16:36	EDIT
📄 egrep.awk	AWK	2.4 KB	2022-11-17 16:36	EDIT
📄 extract.awk	AWK	1.8 KB	2022-11-17 16:36	EDIT
📄 guide.awk	AWK	165 B	2022-11-17 16:36	EDIT
📄 histsort.awk	AWK	283 B	2022-11-17 16:36	EDIT
📄 id.awk	AWK	4.2 KB	2022-11-17 16:36	EDIT
📄 igawk.sh	SH	3.1 KB	2022-11-17 16:36	EDIT
📄 indirectcall.awk	AWK	1.9 KB	2022-11-17 16:36	EDIT
📄 labels.awk	AWK	1014 B	2022-11-17 16:36	EDIT
📄 pi.awk	AWK	341 B	2022-11-17 16:36	EDIT
📄 split.awk	AWK	3.2 KB	2022-11-17 16:36	EDIT
📄 tee.awk	AWK	770 B	2022-11-17 16:36	EDIT
📄 testbits.awk	AWK	736 B	2022-11-17 16:36	EDIT
📄 translate.awk	AWK	1.2 KB	2022-11-17 16:36	EDIT
📄 uniq.awk	AWK	2.9 KB	2022-11-17 16:36	EDIT
📄 wc.awk	AWK	1.8 KB	2022-11-17 16:36	EDIT
📄 wordfreq.awk	AWK	347 B	2022-11-17 16:36	EDIT